Indirection operators

ONLINE HELP
WINDEV, WEBDEV AND WINDEV MOBILE

Version:

Home | Sign in | English

Help / WLanguage / WLanguage syntax / Operators

When should indirection be used?
Identifying the current object
Indirection on a structure
Using the indirection on the paths in an XML document
Limitations
Indirections in Java

WINDEV

WEBDEV

WINDEV Mobile

Others

See also

Indirection operators

In french: Opérateurs d'indirection

The { and } operators are used to access a control, a variable, a class member or a file item by dynamically building the name of control, variable, class member or item.

The { and } operators present several benefits:

Passing in parameter the name of a control, variable, class member or item.
Building the name of a control, variable, class member or item by programming.

To use an indirection on a control of a page, the option "Allow indirections (slows the execution down)" must be checked ("Details" tab in the control description window).

Indirections cannot be performed local variables. Indirections can only be performed on global variables only. An indirection on a local variable of a process will trigger an "unknown element" error.

Example

// Simple indirection
{"NAME"} = CustName // Is equivalent to NAME=CustName
{"NAME"} = {"CU.CUSTNAME"} // Is equivalent to NAME=CU.CUSTNAME
{"CUSTWIN.NAME"} = CustName // Is equivalent to CUSTWIN.NAME=CustName
{"CUSTWIN"+".NAME"} = CustName // Is equivalent to CUSTWIN.NAME=CustName

// Typed indirection
{"Name",indControl} = CustName

// Indirection with a file name in a variable
nFileName is string = "Customer"
{nFileName + ".Name"} = "Smith"
HAdd({nFileName})

// Indirection in a procedure
ControlName is string
ControlName = "EDT_EDIT1" // EDT_EDIT1 is the name of the control
// Call to a procedure used to make a control invisible
Make_Invisible(ControlName)

PROCÉDURE Make_Invisible(ControlN)
{ControlN}..State = Invisible

// Indirection with variable
AliasName is string
AliasName = PreviousWin()
// NAME is the name of the control
// CustName is the value to assign
{AliasName+".NAME"} = CustName
Abbrev is string
ItemName is string
{Abbrev+"."+ItemName} = CustName
{Abbrev+"."+ItemName} = {ControlName}

// Declare a class with two members
MyClass is Class
Member1 is string
Member2 is string
// Display the value of a member
GLOBAL procédure DisplayMember(Number)
// Retrieve the value of the selected global member
Value is string = {"::Member"+Number}
Info(Value)

c is cWord
var is Variable Description
Def is Definition

Def = GetDefinition(c)
// Retrieves the 2nd variable of the class: version of Word
var = Def..Variable[2]

Trace(var..Name) // Displays the variable name
Trace("Version of Word: ",{c, var}) // Displays the Word version

Syntax

Simple indirection Hide the details

{ <Expression> }

<Expression>: Character string

Expression used to identify the control, the variable or the item to use. The element is sought:
among the variables,
according to the number of dots found in the name:
0 dot: search among the controls, then the HFSQL items.
1 dot: search among the HFSQL items, the controls, then the query parameters.
greater than 1 dot: search among the controls.
among the special elements kept for compatibility (_Tabx for example, ...).
A WLanguage error occurs if this expression corresponds to an empty string ("").

Indirection on a class member Hide the details

{ <Expression> }

<Expression>: Character string

Expression used to identify the class member.
If the member is:
global, use the following syntax: {" :: MemberName"}
not global, use the following syntax: {" : MemberName"}
A WLanguage error occurs if this expression corresponds to an empty string ("").

Indirection on a class member Hide the details

{ <Class> , <Member> }

<Class>: Character string

Class instance

<Member>: Character string or Variable Description variable

Corresponds to:
the member name,
a variable of type Variable Description.

Indirection by specifying the element type (optimizes the execution speed) Hide the details

{ <Expression>, <Type> }

<Expression>: Character string

Expression used to identify the control, the variable or the item to use. A WLanguage error occurs if this expression corresponds to an empty string ("").

<Type>: Constant

Constant used to specify the type of sought element:
indControl Element sought among the controls and the groups.
indConnection Element sought among the connections.
indReport Element sought among the reports.
This constant is not available in PHP.
indWindow Element sought among the windows.
This constant is not available in PHP.
indFile Element sought among the files.
indGPW Element sought among the elements of user groupware (used to retrieve the initial status of controls).
This constant is not available in PHP.
indLink Element sought among the links.
This constant is not available in PHP.
indQueryParameter Element sought among the parameters of queries.
indItem Element sought among the items.
indVariable Element sought among the variables.
The element is only sought within the global variables.
indPage Element sought among the pages.
Only the current page is accessible.

Remarks

When should indirection be used?

The indirection can be used for example:

To access the value of an element (control, variable, item, ...):
{s_ControlName} = 10
ControlValue = {s_ControlName}
To use a property:
{s_ControlName}..Height = 10
To programmatically handle a column of a Table control:
{s_ColumnName, indControl}[Row_Number] = 10
To handle a table column:
{s_TableName + "." +s_ColumnName, indControl}[Row_Number] = 10

Identifying the current object

To identify the current object, use the following keywords:

MySelf: the current control
MyWindow: the current window
MyPage: the current page
This keyword is not available.
MyReport: the current report
This keyword is not available.
MySource: the current data source.
MyFile: the file that released the current trigger.

Indirection on a structure

An indirection cannot contain an access to a structure or to a class instance. However, the following syntax can be used:

{<Structure Variable>}: member

Using the indirection on the paths in an XML document

The indirection operators can be used to build the path of an element in an XML document.

Example:

sXMLDoc is string = [
<?xml version="1.0" encoding="UTF-8"?>
<Document>
<VersionInfo>
<Version>21</Version>
<Year>2016</Year>
</VersionInfo>
</Document>
]

xmlExample is xmlDocument = XMLOpen(sXMLDoc, fromString)

sParam is string = "WINDEV_Param"

// Direct reading of information ...
Trace(xmlExample.Document.VersionInfo.Version)

// Reading with part of XML path found in a variable
// (idem if file item, window parameter, method, ...)
sParameter is string = "VersionInfo"
Trace({"xmlExample.Document." + sParameter + ".Version"})

Limitations

The indirection operator allows you to find an element by its name.

Therefore, the following operations are not allowed in an indirection:

access to a member of a class instance or structure instance other than the instance of current class (: and:: ).
access to a subelement in a control or array ([] operator).
access to a substring ([[]] operator).
access to a property (.. operator).
indirection ({ } operator).
call to a procedure or to a method of Automation object.
declaring a variable.

Remarks:

The operators for accessing an element (: and [] and [[]] and .. ) can be used on the element obtained by indirection. For example:
{ <indirection> }: member

{ <indirection> } [index]

{ <indirection> } [[ index ]]

{ <indirection> }..property
To call a procedure identified by its name, use Execute or ExecuteProcess.
To combine these operations dynamically, you have the ability to use the dynamic compilation (see Compile).

Indirections in Java

Indirections are not supported by local variables

Related Examples:

Unit examples (WINDEV): The indirections

[ + ] Handling indirections via the { and } operators.
The { and } operators are used to access a control or a file item by dynamically building the control name or the item name.
This program, powered by WINDEV, implements the indirection mechanism on the window controls to manage the "Undo-Redo" and "Cut-Copy-Paste" features in a generic way.

Unit examples (WEBDEV): The indirections

[ + ] This example explains how to use the indirections on a variable.

You will notice that the indirections are available for the controls, the items, the links, etc. The principle is identical to the one presented in this example.

Unit examples (WINDEV Mobile): The indirections

[ + ] Using the indirection { and } operators.
The { and } operators are used to access a control or a file item by dynamically building the control name or the item name.
This example implements the indirection mechanism on the window controls to manage the "Undo-Redo" and "Cut-Copy-Paste" features in a generic way.