ONLINE HELP WINDEV, WEBDEV AND WINDEV MOBILEVersion: 2425262728
• Other types of arrays
• Procedure: Declaring an array parameter
• Passing an array as parameter to a procedure
• WLanguage functions and arrays
• Array of arrays, associative array, queue, stack, list
• Limitations: Elements of an array
• Arrays in the classes
• Adding the content of a structure to an array of structures without using a variable of the structure
WINDEV
WEBDEV
WINDEV Mobile
Others
Array (Type of variable)
In french: Tableau (Type de variable)
An array is a structured type that is used to group a set of elements of the same type. Each element of the array can be accessed by its index.
Example
// Declares an array initialized with the names of days of the week
DayArray is array of strings = ["Monday", "Tuesday", "Wednesday", "Thursday", "Friday"]
// Handles the array
DayArray[2] // Returns "Tuesday"
// Declares an array of integers
ValueArray is array of int
// Populates the array of integers by adding values
Add(ValueArray, 5)
Add(ValueArray, 10)
Add(ValueArray, 15)
// Browses the array values
FOR EACH x OF ValueArray
// x is successively equal to 5, 10, 15
...
END
// Declares an array of integers
ValueArray is array <growth=1> of int
// Enlarges the array to insert the value 1: 10
ValueArray[1] = 10
// Enlarges the array to insert the value 2: 20
ValueArray[2] = 20
// Enlarges the array to insert the value 3: 30
ValueArray[3] = 30
// Browses the array values
FOR EACH x OF ValueArray
// x is successively equal to 10, 20, 30
END
// Declares an array of integers
ValueArray is array <growth=N> of int
// Enlarges the array to insert the value 1: 10
ValueArray[1] = 10
// Enlarges the array to insert the value 5: 50
// The values 2, 3 and 4 are initialized to 0
ValueArray[5] = 50
// Browses the array values
FOR EACH x OF ValueArray
// x is successively equal to 10, 0, 0, 0, 50
END
// Declare an Array of arrays
arrMyArray is array of strings
nArrIndex is int

nArrIndex = Add(arrMyArray)
Add(arrMyArray[nArrIndex], "January")
Add(arrMyArray[nArrIndex], "300")
nArrIndex = Add(arrMyArray)
Add(arrMyArray[nArrIndex], "February")
Add(arrMyArray[nArrIndex], "600")

Trace(arrMyArray[1,1]) // Displays "January"
Trace(arrMyArray[1,2]) // Displays "300"
Syntax

Declaring a one-dimensional array

<Array name> is array [<growth>] [ [<Dimension 1>] ] <Type of array elements>
Example:
``` arrString is array <growth=N> [10] strings arrInt is array [5] ints ```
<Array name> is array [<growth>] of [<Dimension>] <Type of array elements>
<Array name>:
Name of the array variable to declare.
<growth>:
Optional mode for enlarging the array:
• nothing (by default) or "<growth=0>": the array is not automatically enlarged. For example, a runtime error will occur if the array contains 5 elements and if the program accesses the element 6 or 100.
• "<growth>" or "<growth=1>": the array is automatically enlarged by 1 element. For example, if the array contains 5 elements and if the program accesses the element 6, the array is automatically enlarged to handle the element 6 ; a runtime error will occur if the program accesses the element 100.
• "<growth=N>": the array is automatically enlarged by the number of necessary elements. For example, if the array contains 5 elements and if the program accesses the element 6, the array is automatically enlarged to handle the element 6 ; if the program accesses the element 100, the array is automatically enlarged to handle the element 100. The intermediate elements are initialized with the default value for this type of array elements.
Remark: To enlarge an array with several dimensions, use Dimension.
<Dimension>:
Optional dimension of the array. This parameter can:
• be unspecified or correspond to * or 0: the array is initialized empty.
• correspond to a constant value or to an integer variable: the array is initialized with the specified number of elements. Each element is initialized with the default value of its type.
<Type of array elements>:
Type of the elements found in the array. See the different types of variables.
Remark: The elements that make up the array can also be arrays, fixed arrays, associative arrays, queues, stacks or lists.

Declaring an array with several dimensions (up to 10)

<Array name> is array of [ [<Dimension 1> [, <Dimension 2>]...[, <Dimension 10>]] ] <Type of array elements>
Example:
``` arrString is array [10,20] strings arrInt is array [3,5,2] ints ```
<Array name> is array of [<Dimension 1> [by <Dimension 2>] ... [by <Dimension 10>]] <Type of array elements>
OR
<Array name> is array of [<Dimension 1> [, <Dimension 2>]... [, <Dimension 10>]] <Type of array elements>
<Array name>:
Name of the array variable to declare.
<Dimension 1>...<Dimension 10>:
Dimension 1 to 10 of the array. The value of the dimension can correspond to:
• * or 0: the dimension is initialized with 0 element.
• a constant value or an integer variable: the dimension is initialized with the specified number of elements. Each element is initialized with the default value of its type.
<Type of array elements>:
Type of the elements found in the array. See the different types of variables.
Remark: The elements that make up the array can also be arrays, fixed arrays, associative arrays, queues, stacks or lists.

Declaring an array parameter

One-dimensional array:
<Parameter name> is array of [<Dimension>] <Type of array elements>

Two-dimensional array
<Parameter name> is array of <Dimension 1> by <Dimension 2> <Type of array elements>

N-dimensional array
<Parameter name> is array of [<Dimension 1> [by <Dimension 2>] ... [ by <Dimension N>]] <Type of array elements>
<Parameter name>:
Name of the array parameter to declare.
<Dimension n>:
<Dimension> may not be specified, it may correspond to * , 0 or to a constant value.
<Type of array elements>:
Type of the elements found in the array. See the different types of variables.
Remark: The elements that make up the array can also be arrays, fixed arrays, associative arrays, queues, stacks or lists.

Referring to an array

Referring to an element in a one-dimensional array:
<Array name>[Index1]

Referring to an element in a two-dimensional array:
<Array name>[Index1, Index2]
OR
<Array name>[index1][index2]

Referring to an element in a n-dimensional array:
<Array name>[Index1,...,IndexN]
OR
<Array name>[Index1]...[IndexN]
<Array name>:
Name of the array to use.
<Index1>:
Index of the element for the 1st dimension.
<Index2>:
Index of the element for the 2nd dimension.
<IndexN>:
Index of the element for the Nth dimension (N <= 10).
Remarks

Other types of arrays

The Array keyword is used to define an array. Other types of "advanced" arrays are available:

Procedure: Declaring an array parameter

An array can be passed as parameter to a procedure. For example:
// Adds a customer into the array
PROCÉDURE AddCustomer(arrCustomer is array of * CCustomer,
sName is string,
sInfo is string)
// Builds the new customer object
c is CCustomer(sName, sInfo)
// Adds the object into the array
Add(arrCustomer, c)

Remarks:
• The type of the elements found in the array passed as parameter must be the same as the one of the declaration.
• The number of dimensions in the array passed as parameter must be the same as the one of the declaration.
• The number of elements found in each dimension of the array passed as parameter must correspond to the declaration:
• if the number of elements for the dimension is *, no check is performed.
• if the number of elements for the dimension is specified, the number of elements must be identical.
• No check is performed during the compilation: checks are performed at runtime.

Passing an array as parameter to a procedure

An array can be passed as parameter to a procedure. To do so, use the following syntax:
<Procedure name>(<Array name>)

For example:
SuppArray is array of 10 by 50 strings
// Call to the DisplayArray procedure
DisplayArray(SuppArray)

WLanguage functions and arrays

Several WLanguage functions can be used to handle the arrays. You have the ability to perform sorts, searches, etc. For more details, see Array management functions.

Array of arrays, associative array, queue, stack, list

The following syntaxes are supported:
<variable> is array of arrays of int
<variable> is array of arrays of 5 int
<variable>  is array of 5 arrays of int
<variable> is array of 5 arrays of 5 int

<variable> is array of fixed arrays of 5 int
<variable> is array of 5 fixed arrays of 5 int

<variable> is array of associative arrays of int
<variable> is array of associative arrays (withDuplicates) of int
<variable> is array of associative arrays (withDuplicates,wlInt) of int
<variable> is array of 5 associative arrays of int
<variable> is array of 5 associative arrays (withDuplicates) of int
<variable> is array of 5 associative arrays (withDuplicates,wlInt) of int

<variable> is array of queues of int
<variable> is array of 5 queues of int

<variable> is array of stacks of int
<variable> is array of 5 stacks of int

<variable> is array of lists of int
<variable> is array of 5 lists of int

Limitations: Elements of an array

• An array can be made of classes only if these classes have a constructor without parameter (or with optional parameters).
• An array cannot be made of composite variables.
• And array cannot be made of arrays.
• No array of classes or array of structures can be created.

Arrays in the classes

When copying instances of classes, all the members of the class are copied into the new instance except for the arrays. Therefore, if the value of an array member is modified, this value is modified in all the instances.
To get independent arrays in all instances of classes, a local array must be declared as follows:
SystemClass is Class
aDefaultArray is local array of 1 int
END

Adding the content of a structure to an array of structures without using a variable of the structure

If you are using an array of structures with few members, it may be easier to directly add a structure by using the [ ] operator (square brackets).
For example, for the following structure:
// Structure to store a letter and its ASCII code
STKey is Structure
sKey is string
nAsciiCode is int
END
// Array of structures
arrKeys is array of STKey

In most cases, content is added by using a variable of a type declared in the structure:
// Temporary structure for the addition
stAKey is STKey
// Stores the letter A
stAKey.sKey = "A"
stAKey.nAsciiCode = Asc("A")
arrKeys.Add(stAKey)

With the [ ] operator, you get better legibility:
// Stores the letter A
arrKeys.Add(["A", Asc("A")])
Related Examples:
 Unit examples (WINDEV): Using the arrays [ + ] Using the array type in WLanguage.
Minimum version required
• Version 9
This page is also available for…
 Comments
 ARRAY DIMENSIONAL VARIAVEL
 arrayAntes is array of 1 by 4 STRINGArrayDeleteAll(arrayAntes) Dimension(arrayAntes,1,4) X is int = 1FOR EACH t000_frutas arrayAntes[X,1]=t000_frutas.t000_frutas_ID arrayAntes[X,2]=t000_frutas.t000_fruta arrayAntes[X,3]=t000_frutas.t000_ordem arrayAntes[X,4]=t000_frutas.t000_status X++ Dimension(arrayAntes, X, 4)END
 BOLLER
 18 Jul. 2019
 item limit
 I have a customer who is reaching the 65,000 item limit and was wondering if an array counted as one item or that if each element in the array counted towards the total. Like MyArray ["john","mary","frank"] is that one item towards the limit or three?
 DECKFURNITURE
 29 Mar. 2019
 Send a report | Local help